ActionScript3.0入門ノート

package {
	import fl.controls.TextArea;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.system.System;
	import flash.events.Event;
	import flash.text.TextFormat;

	public class TextdataLoader {
		var txtArea:TextArea;
		
		//コンストラクタ
		function TextdataLoader(ta:TextArea, url:String, shiftJIS:Boolean) {
			txtArea = ta;
			var format:TextFormat = new TextFormat();
			format.size = 18;
			txtArea.setStyle("textFormat",format);
			//URLLoader作成
			var txtLoader:URLLoader = new URLLoader();
			txtLoader.dataFormat = URLLoaderDataFormat.TEXT;
			txtLoader.addEventListener(Event.COMPLETE, onLoaded);
			//URL
			var urlReq:URLRequest = new URLRequest(url);
			//Shift-JISならばtrue
			System.useCodePage = shiftJIS;
			//読み込み開始
			txtLoader.load(urlReq);
		}
		//読み込んだテキストを表示する
		function onLoaded(event:Event):void {
			txtArea.text = txtLoader.data;
		}
	}
}

TextdataLoaderクラスを試すには、TextAreaコンポーネントのインスタンスreport_txtを作り、メインのタイムラインのフレームアクションに次のスクリプトを書きます。この例ではSWFファイルと同じ階層にあるtextdataフォルダの中のテキストファイルchigasaki.txtを読み込みます。テキストファイルの文字コードはUnicodeでもShift-JISでも構いません。このサンプルではShift-JISで保存してあります。

fig10-01-02 ステージはTextAreaコンポーネントのインスタンスreport_txtを作ります。

[:sample:] textdataLoader_test.fla
例：メインのタイムラインのフレームアクション

import TextdataLoader;
var url:String = "textdata/chigasaki.txt";
var shiftJIS:Boolean = true;
var imgLoaderObj:TextdataLoader = new TextdataLoader(report_txt, url, shiftJIS);

外部テキストファイルの読み込みはURLLoaderクラスを使います。URLLoaderクラスではテキストだけでなくバイナリーやURLエンコード形式の変数を受信できるので、テキストを読み込む場合にはURLLoaderクラスのインスタンスのdataFormatの値をURLLoaderDataFormat.TEXT（"text"）にします。ただ、dataFormatの初期値はURLLoaderDataFormat.TEXTなので設定しなくても構いません。

[:note:]
dataFormatの値はバイナリを読み込む場合はURLLoaderDataFormat.BINARY、URLエンコード形式の変数を読み込む場合はURLLoaderDataFormat.VARIABLESにします。

例：URLLoader作成

var txtLoader:URLLoader = new URLLoader();
txtLoader.dataFormat = URLLoaderDataFormat.TEXT;

読み込むテキストのURLはLoaderクラスと同様にURLRequestオブジェクトにし、txtLoader.load(urlReq)のようにして読み込みを開始します。ここで、読み込むテキストの文字コードの初期値がUnicodeである点に注意が必要です。Shift-JISで保存してあるテキストを読み込む場合にはSystem.useCodePageの値をtrueに設定します。

例：Shift-JISで読み込み開始

//URL
var urlReq:URLRequest = new URLRequest(url);
//Shift-JISならばtrue
System.useCodePage = shiftJIS;
//読み込み開始
txtLoader.load(urlReq);

読み込んだテキストデータはURLLoaderのインスタンスのdataプロパティに格納されます。そこで、読み込み完了のEvent.COMPLETEイベントを受けたならば、txtLoader.dataからテキストデータを取り出して表示します。

例：読み込んだテキストを表示する

function onLoaded(event:Event):void {
	txtArea.text = txtLoader.data;
}

TextAreaコンポーネントの書式はTextFormatクラスのオブジェクトformatを作ってプロパティを設定し、setStyle("textFormat",format)で設定します。

例：TextAreaコンポーネントの書式設定

var format:TextFormat = new TextFormat();
format.size = 18;
txtArea.setStyle("textFormat",format);