package {
 import jp.progression.commands.display.*;
 import jp.progression.commands.*;
 import jp.progression.scenes.*;
 import jp.progression.casts.getInstanceById;
 import jp.progression.casts.getInstancesByGroup;
 import jp.progression.commands.tweens.DoTweener;
 import jp.progression.commands.lists.*;
 import pages.*
 
 public class IndexScene extends SceneObject {
  public function IndexScene() {
   //ブラウザのタイトル。
   title = "Top";
   //コンテンツ
   var castSp:*;
   for (var i:int=0;i < 20;i++){
    if(i%2){
     //偶数番のキャストを作る
      castSp = new BallCastSprite();
      castSp.id = "sp"+i; //インスタンスid
      castSp.group = "ball";//インスタンスグループ
      castSp.scaleX=castSp.scaleY=0.4;
     }else{
      //奇数番のキャストを作る
      castSp = new BoxCastSprite();
      castSp.id = "sp"+i;//インスタンスid
      castSp.group = "box";//インスタンスグループ
     }
     //キャストをコンテナに並べる
     castSp.x = i%5*100+40;
     castSp.y = int(i/5)*90+40;
     (new AddChild(container, castSp)).execute();
   }

  }
  //このシーンをロードしたらアニメーションを開始する
  protected override function atSceneLoad():void {
   //インスタンスグループballのアニメーションのコマンドリストを作る
   var ballList:Array = getInstancesByGroup("ball");
   var animeList1:SerialList = new SerialList();
   for (var i:int=0;i < ballList.length;i++){
    animeList1.addCommand( new DoTweener(ballList[i],{scaleX:1,scaleY:1,time:0.5,transition:"easeOutElastic"}));
    animeList1.addCommand( new DoTweener(ballList[i],{scaleX:0.4,scaleY:0.4,time:0.5,transition:"easeOutElastic"}));
   };
   //インスタンスグループboxのアニメーションのコマンドリストを作る
   var boxList:Array = getInstancesByGroup("box");
   var animeList2:ParallelList = new ParallelList();
   for (var j:int=0;j < boxList.length;j++){
    animeList2.addCommand( new DoTweener(boxList[j],{rotation:90,time:1,transition:"easeOutElastic"}));
   }
    //インスタンスidを１個選んでアニメーションをループさせる
    var no:int = Math.floor(Math.random()*20);
    var sp:* = getInstanceById("sp"+no) ;
     var animeList3:LoopList = new LoopList();
    animeList3.addCommand(new DoTweener(sp,{scaleX:1.5,scaleY:1.5,time:1,transition:"easeOutElastic"}));
    animeList3.addCommand(new DoTweener(sp,{scaleX:0.4,scaleY:0.4,time:1,transition:"easeOutElastic"}));  
   //コマンドリストの実行
    addCommand(animeList1, animeList2, animeList3);
  }
 }
}

ブラウザで無料ではじめるActionScript 3.0 ―It's a wonderfl world―

執筆陣も内容も豪華です！
面白法人カヤックFlashチーム（大塚雅和、小林太郎、道家陽介、中野総子、原真人、日高一明、村井孝至）、野中文雄、大重美幸、高輪知明nutsu、イズカワタカノブkatamari、村山健undefined、梅原宗士水玉製作所、小林陽介ローハイド、池田泰延clockmaker、吉川佳一BOW、小林茂yapan.org（敬称略）

Flash3Dコンテンツ制作のためのPapervision3D入門

TheFlashBlog iPhoneカテゴリ

swfを試す。

サンプルファイル一式→ LiquidLayout_1.zip

なお、このバージョンはProgression 4.0.1 Public Beta1.2で作ってあります。1.1ではNextSceneボタンとPreviousSceneボタンが正しく動作しません。

そうそう、シーンを進めると一瞬だけ上に現れるバーはプログレスバーなんですけどね。ちゃんと動いていいるのかな？？って感じです。

package pages{
  import jp.progression.casts.*;
  import jp.progression.commands.display.*;
  import jp.progression.commands.lists.*;
  import jp.progression.commands.net.*;
  import jp.progression.commands.tweens.*;
  import jp.progression.commands.*;
  import flash.display.Loader;
  import flash.net.URLRequest;
  
  /**
   * ...2009.10.27b
   * @author ...oshige
   */
  public class ThePage extends CastMovieClip {
    private var _url:String;
    
    public function ThePage(url:String, initObject:Object=null) {
      _url = url;
      // 親クラスを初期化します。
      super(initObject);
    }
    
    protected override function atCastAdded():void {
      addCommand(
         new Prop(this,{y:-stage.stageHeight}),
         //swf読み込み
        new LoadSWF(new URLRequest(_url), null, {
          onProgress:function():void {
            trace(this.bytesLoaded + " / " + this.bytesTotal + " (" + this.percent + "%)" );
          },
          onComplete:function():void{
            var ld:Loader = this.loader;
            self.addChild(ld);trace("self=",self);
            ld.x=(stage.stageWidth-ld.width)/2;
            ld.y=(stage.stageHeight-ld.height)/2;
          }
        }),
         new DoTweener( this, {y:0,time:1, transition:"easeinoutsin"} )
      );
    }
    
    protected override function atCastRemoved():void {
      addCommand(
          new DoTweener( this, { y:stage.stageHeight, time:1, transition:"easeinoutsin"} ),
          //読み込んだswfを消すために行う
          new RemoveAllChildren(this)
      );
    }
  }
}

package pages{
	import jp.progression.casts.*;
	import jp.progression.commands.display.*;
	import jp.progression.commands.lists.*;
	import jp.progression.commands.net.*;
	import jp.progression.commands.tweens.*;
	import jp.progression.commands.*;
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.net.URLRequest;
	/**
	 * ...2009.10.27
	 * @author ...oshige
	 */
	public class ThePage extends CastMovieClip {
		private var _url:String;
		private var page:CastMovieClip;
		public function ThePage(initObject:Object=null) {
			// 親クラスを初期化します。
			super(initObject);
			_url = initObject.url;
			page = this;
		}
		
		protected override function atCastAdded():void {
			var list:SerialList = new SerialList();
			list.addCommand(
				new Prop(page,{y:-stage.stageHeight}),
				new LoadSWF(new URLRequest(_url)),
				function():void {
					var loader:Loader = Loader( this.latestData );
					list.insertCommand(
						new Prop(loader, {x:(stage.stageWidth-loader.width)/2,y:(stage.stageHeight-loader.height)/2}),
						new AddChild(page, loader)
					)
				},
				new DoTweener( page, { y:0,time:1, transition:"easeinoutsin"} )
			)
			list.execute();
		}
		
		protected override function atCastRemoved():void {
			addCommand(
		 	 	new DoTweener( page, { y:stage.stageHeight, time:1, transition:"easeinoutsin"} ),
		  		//読み込んだswfを消すために行う
		  		 new RemoveAllChildren(this)
			);
		}
	}
}

package pages{
	import jp.progression.casts.*;
	import jp.progression.commands.display.*;
	import jp.progression.commands.lists.*;
	import jp.progression.commands.net.*;
	import jp.progression.commands.tweens.*;
	import jp.progression.commands.*;
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.net.URLRequest;
	/**
	 * ...2009.10.27
	 * @author ...oshige
	 */
	public class ThePage extends CastMovieClip {
		private var _url:String;
		private var page:CastMovieClip;
		public function ThePage(initObject:Object=null) {
			// 親クラスを初期化します。
			super(initObject);
			_url = initObject.url;
			page = this;
		}
		
		private function loadSWF():void {
			//pageコンテンツをURLから読み込む（swf、画像）
			var ldswf:LoadSWF = new LoadSWF(new URLRequest(_url));
			ldswf.onProgress = function():void {
			 	trace(ldswf.bytesLoaded + " / " + ldswf.bytesTotal + " (" + ldswf.percent + "%)" );
			};
			ldswf.onComplete = function():void{
				var ld:Loader = this.loader;
				 page.addChild(ld);
				ld.x=(stage.stageWidth-ld.width)/2;
				ld.y=(stage.stageHeight-ld.height)/2;
			};
			ldswf.execute();
		}

		protected override function atCastAdded():void {
			addCommand(
			   new Prop(page,{y:-stage.stageHeight}),
			   //swf読み込み
			   new Func(loadSWF),
			   new DoTweener( page, {y:0,time:1, transition:"easeinoutsin"} )
			);
		}
		
		protected override function atCastRemoved():void {
			addCommand(
		 	 	new DoTweener( page, { y:stage.stageHeight, time:1, transition:"easeinoutsin"} ),
		  		//読み込んだswfを消すために行う
		  		 new RemoveAllChildren(this)
			);
		}
	}
}

var list:SerialList = new SerialList();
list.addCommand(  
 new Trace("コマンドスタート"),  
 function ():void{  
    list.addCommand(new Trace("addCommand1のタイミング"));
    list.insertCommand(new Trace("insertCommandのタイミング"));  
    list.addCommand(new Trace("addCommand2のタイミング")); 
 },  
    new Trace("コマンド終わり！")  
) 
trace("executeの前----------");
list.execute();
trace("executeの後----------");

executeの前----------
コマンドスタート
insertCommandのタイミング
コマンド終わり！
addCommand1のタイミング
addCommand2のタイミング
executeの後----------

swfを試す。
sceneCを直接開く。

サンプルファイル一式→ LoadSWF_pages3.zip

 protected override function atSceneDescend():void {
  stage.removeEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
  //シーンからロゴ退場、パネル登場
  addCommand(
    new DoTweener(logo,{x:30, y:30, scaleX:1, scaleY:1,time:1}),
   new DoTweener( uiPanel, { y:stage.stageHeight - 60, time:1 } )
  );
 }

  protected override function atCastAdded():void {
  	addCommand(
  	   new Prop(this,{x:20,y:-stage.stageHeight}),
  	   //swf読み込み
  	   new Func(loadSWF),
  	   new DoTweener( this, { y:20,time:1, transition:"easeinoutsin"} )
  	);
  }

  private function loadSWF():void {
  	//pageコンテンツをURLから読み込む（swf、画像）
  	var ldswf:LoadSWF = new LoadSWF(new URLRequest(_url));
  	ldswf.onProgress = function():void {
  	 	trace(ldswf.bytesLoaded + " / " + ldswf.bytesTotal + " (" + ldswf.percent + "%)" );
  	};
  	ldswf.onComplete = function():void{
  	   	 addChild(this.loader);
  	};
  	ldswf.execute();
  }

  protected override function atCastRemoved():void {
  	addCommand(
  	  new DoTweener( this, { y:stage.stageHeight, time:1, transition:"easeinoutsin"} ),
  	  //読み込んだswfを消すために行う
  	   new RemoveAllChildren(this)
  	);
  }

var list:SerialList = new SerialList();
list.addCommand(
  new LoadSWF(new URLRequest("pageA.swf")),
  function():void {
      var loader:Loader = Loader( this.latestData );
      addChild(loader);
  }
)
list.execute();

var list:SerialList = new SerialList();
var loader:Loader = new Loader();
list.addCommand(
  new LoadSWF(new URLRequest("pageA.swf"),loader),
  new AddChild(this, loader)
)
list.execute();

public class ThePage extends CastMovieClip {
	public function ThePage( initObject:Object = null ) {
		// 親クラスを初期化します。
		super( initObject );
		//pageコンテンツをURLから読み込む（swf、画像）
		var list:SerialList = new SerialList();
		list.addCommand(
				     new LoadSWF(new URLRequest(initObject.url)),
						 function():void{
						 var loader:Loader = Loader( this.latestData );
						 addChild(loader);
					 }
		);
		list.execute();
	}

public class TheScene extends SceneObject {
	private var page:ThePage;
	public function TheScene( name:String = null, initObject:Object = null ) {
		// 親クラスを初期化する
		super( name, initObject );
		// このシーンタイトル
		title = initObject.title;
		//このシーンの中身
		page = new ThePage(initObject);
	}
	//シーンが読み込まれる
	protected override function atSceneLoad():void {
		//シーンにコンテンツを追加する
		addCommand(
				    new AddChildAt(container, page,0)
		);
	}

public class IndexScene extends SceneObject {
	private var uiPanel:CastSprite;
	private var logo:MovieClip;
	
	public function IndexScene() {
		// このシーンタイトル
		title = "IndexScene_Logo";
		//このシーンの中身
		logo = new oshigeLogo();
		//子シーンを追加する
		var sceneA:TheScene = new TheScene("sceneA",{title:"pageA", url:"pages_swf/pageA.swf"});
		var sceneB:TheScene = new TheScene("sceneB",{title:"pageB", url:"pages_swf/pageB.swf"});
		var sceneC:TheScene = new TheScene("sceneC",{title:"pageC", url:"pages_swf/pageC.swf"});
		addScene(sceneA);
		addScene(sceneB);
		addScene(sceneC);